 10 D$ =  CHR$ (4)
 20  HOME 
 30  PRINT "DRIVE 2 - ADVENTURE SOURCE DISK"
 40  PRINT 
 50  INPUT "PRESS RETURN WHEN READY";X$
 60  DIM CT(150),XT(150),PL(150),PH(150),LN$(999)
 70  PRINT D$;"OPEN T.TRV.TEXT"
 80  PRINT D$;"READ T.TRV.TEXT"
 90 PL(0) = 0:PH(0) = 0
 100 C = 0:L = 0:N = 0:P = 3:A$ = ""
 110 LN$(0) = "0,0,0"
 120  GOSUB 380
 130 L = L + 1
 140  PRINT ".";
 150 PH(L) =  INT (P / 256)
 160 PL(L) =  INT (P - (PH(L) * 256))
 170  IF I = 999 THEN  GOTO 480
 180 OL = I
 190  GOSUB 380:NL = I
 200  GOSUB 380:CN = I
 210  GOSUB 380:XX = I
 220  GOSUB 380
 230 J = CN
 240  IF CN = 0 THEN 260
 250 C = C + 1:CT(C) = CN:XT(C) = XX:J = C
 260 VB = I: GOSUB 380
 270 N = N + 1
 280 P = P + 3
 290  IF I = 999 THEN 320
 300 LN$(N) =  STR$ (J) + "," +  STR$ (NL) + "," +  STR$ (VB)
 310  GOTO 240
 320  GOSUB 380
 330  IF I <  > OL THEN 360
 340 LN$(N) =  STR$ (J) + "," +  STR$ (NL) + "," +  STR$ (VB)
 350  GOTO 170
 360 LN$(N) =  STR$ (J + 128) + "," +  STR$ (NL) + "," +  STR$ (VB)
 370  GOTO 130
 380  IF A$ <  >  CHR$ (13) THEN 420
 390 A$ = ""
 400 I = 999
 410  RETURN 
 420 I = 0
 430  GET A$
 440  PRINT A$;
 450  IF A$ = "," OR A$ =  CHR$ (13) THEN  RETURN 
 460 I = (I * 10) +  VAL (A$)
 470  GOTO 430
 480  PRINT 
 490  PRINT D$;"CLOSE T.TRV.TEXT"
 500  PRINT D$;"OPEN T.TRV,D2"
 510  PRINT D$;"DELETE T.TRV"
 520  PRINT D$;"OPEN T.TRV"
 530  PRINT D$;"WRITE T.TRV"
 540  PRINT " SKP 1"
 550  PRINT " REP 56"
 560  PRINT "* TRAVEL TABLES
 570  PRINT " REP 56"
 580  PRINT "XLCTRVL DFB 0"
 590 J = 0
 600  FOR I = 1 TO L - 1
 610 J = J + 1
 620  IF J = 1 THEN  PRINT " DFB ";PL(I);: GOTO 650
 630  PRINT ",";PL(I);
 640  IF J = 10 THEN  PRINT :J = 0
 650  NEXT I
 660  IF J <  > 0 THEN  PRINT 
 670  PRINT " SKP 1"
 680  PRINT "XLCTRVH DFB 0"
 690 J = 0
 700  FOR I = 1 TO L - 1
 710 J = J + 1
 720  IF J = 1 THEN  PRINT " DFB ";PH(I);: GOTO 750
 730  PRINT ",";PH(I);
 740  IF J = 10 THEN  PRINT :J = 0
 750  NEXT I
 760  IF J <  > 0 THEN  PRINT 
 770  PRINT " SKP 1"
 780  PRINT "XTVTBL EQU *"
 790  FOR I = 0 TO N
 800  PRINT " DFB ";LN$(I)
 810  NEXT I
 820  PRINT " SKP 1"
 830  PRINT "XTVCND DFB 0"
 840 J = 0
 850  FOR I = 1 TO C
 860 J = J + 1
 870  IF J = 1 THEN  PRINT " DFB ";CT(I);: GOTO 900
 880  PRINT ",";CT(I);
 890  IF J = 10 THEN  PRINT :J = 0
 900  NEXT I
 910  IF J <  > 0 THEN  PRINT 
 920  PRINT " SKP 1"
 930  PRINT "XTVXXX DFB 0"
 940 J = 0
 950  FOR I = 1 TO C
 960 J = J + 1
 970  IF J = 1 THEN  PRINT " DFB ";XT(I);: GOTO 1000
 980  PRINT ",";XT(I);
 990  IF J = 10 THEN  PRINT :J = 0
 1000  NEXT I
 1010  IF J <  > 0 THEN  PRINT 
 1020  PRINT " SKP 1"
 1030  PRINT D$;"CLOSE T.TRV"
